15.4.5 Wat is het gedeclareerd bedrag per zorgsector?

Concepten

• Vestiging
• Vestigingsnummer
• ZorgDeclaratie
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• goedgekeurd
• heeft datawaarde
• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.5
2# Parameters: ?startperiode, ?eindperiode, ?zorgkantoor
3# Ontologie: versie 3.0.0
4
5PREFIX onz-g:     <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg:  <http://purl.org/ozo/onz-zorg#>
7PREFIX xsd:       <http://www.w3.org/2001/XMLSchema#>
8PREFIX onz-org:   <http://purl.org/ozo/onz-org#>
9PREFIX rdfs:      <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
11
12SELECT DISTINCT 
13    ?Indeling 
14    ?Procent_gedeclareerd_bedrag_GGZ_W ?Procent_gedeclareerd_bedrag_GGZ_B ?Procent_gedeclareerd_bedrag_LG ?Procent_gedeclareerd_bedrag_LVG 
15	?Procent_gedeclareerd_bedrag_VG ?Procent_gedeclareerd_bedrag_ZGAUD ?Procent_gedeclareerd_bedrag_ZGVIS ?Procent_gedeclareerd_bedrag_VV
16{
17    {
18        SELECT 
19            ("Totaal organisatie" AS ?Indeling)
20            ((ROUND(SUM(?ggzWAmount) / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_GGZ_W)
21            ((ROUND(SUM(?ggzBAmount) / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_GGZ_B)
22            ((ROUND(SUM(?lgAmount)   / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_LG)
23            ((ROUND(SUM(?lvgAmount)  / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_LVG)
24            ((ROUND(SUM(?vgAmount)   / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_VG)
25            ((ROUND(SUM(?zgaudAmount)/ SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_ZGAUD)
26            ((ROUND(SUM(?zgvisAmount)/ SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_ZGVIS)
27            ((ROUND(SUM(?vvAmount)   / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_VV)
28        WHERE {
29 			#BIND("2024-01-01"^^xsd:date AS ?startperiode)
30            #BIND("2024-12-31"^^xsd:date AS ?eindperiode)
31
32            ?declaratie
33                a onz-g:CareInvoice ;
34                onz-g:hasDate ?date ;
35                onz-g:goedgekeurd "true"^^xsd:boolean ;
36            	onz-fin:heeftGeldBedrag ?amount ;
37                onz-g:isAbout ?zorgproces .
38
39            FILTER(?startperiode <= ?date && ?date <= ?eindperiode)
40
41            ?zorgproces
42                a onz-g:CureAndCareProcess ;
43                onz-g:definedBy ?indicatie ;
44                onz-g:hasPerdurantLocation ?locatie .
45
46            ?indicatie
47                a onz-zorg:WlzIndicatie ;
48                onz-g:hasPart/onz-g:isAbout ?sector .
49
50            # Per sectorbedrag
51            BIND(IF(?sector = onz-zorg:GGZ-W, ?amount, 0) AS ?ggzWAmount)
52            BIND(IF(?sector = onz-zorg:GGZ-B, ?amount, 0) AS ?ggzBAmount)
53            BIND(IF(?sector = onz-zorg:LG,     ?amount, 0) AS ?lgAmount)
54            BIND(IF(?sector = onz-zorg:LVG,    ?amount, 0) AS ?lvgAmount)
55            BIND(IF(?sector = onz-zorg:VG,     ?amount, 0) AS ?vgAmount)
56            BIND(IF(?sector = onz-zorg:ZGAUD,  ?amount, 0) AS ?zgaudAmount)
57            BIND(IF(?sector = onz-zorg:ZGVIS,  ?amount, 0) AS ?zgvisAmount)
58            BIND(IF(?sector = onz-zorg:VV,     ?amount, 0) AS ?vvAmount)
59
60            # Locatie triple structuur (voor behoud URI context, wordt niet geprojecteerd)
61            ?locatie onz-g:partOf* ?vestiging_uri .
62            ?vestiging_uri a onz-org:Vestiging .
63        }
64    }
65
66    # Extra locatie-informatie voor mapping naar zorgkantoor (wordt niet in output opgenomen)
67    ?vestiging_uri
68        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
69
70    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
71
72    ?pc_gebied 
73        onz-g:identifiedBy ?postcode ;
74        onz-g:partOf+ ?zk_regio .
75
76    ?zk_regio a onz-org:ZorgkantoorRegio .
77    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
78
79    {
80        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
81        ?vest_nr a onz-org:Vestigingsnummer ;
82                 onz-g:hasDataValue ?vestiging .
83    } UNION {
84        # Organisatieniveau toevoegen als 'vestiging'
85        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
86        BIND("Totaal organisatie" AS ?vestiging)
87        BIND("n.v.t." AS ?zk_vestiging)
88    }
89
90    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
91}
92